﻿title   ZOBEX HD Disk Format Program (27-Sep-81)
;########################################################;
;#                                                      #;
;#          ZOBEX HD DISK FORMATTING PROGRAM            #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  Written by: Frank MacLachlan                        #;
;#  Date:       13-Aug-81                               #;
;#  Revised:    27-Sep-81                               #;
;#                                                      #;
;#  To assemble:                                        #;
;#      zasm hdfmt.aaz                                  #;
;#                                                      #; 
;#  To link:                                            #;
;#      l80 hdfmt,z80lib/s,hddfdat,hdfmt/n/e:start      #;
;#                                                      #;
;########################################################;


;########################################################;
;#              system definitions                      #;
;########################################################;


;       external references:


        global  boot            ; CP/M reboot vector adr
        global  trkbuf          ; track image buffer
        global  stktop          ; initial stack pointer setting


;       Entry points:


        global  start           ; start of program
        global  drive           ; current drive no
        global  ilfact          ; current interleave factor




;       Assembly options:


DEBUG   equ     0               ; assemble debugging code if <> 0


;       misc definitions:


MAXCYL  equ     152             ; maximum cylinder number
MAXSEC  equ     53              ; maximum sector number
SECSIZ  equ     128             ; sector size in bytes
RATE    equ     0000b           ; step rate = 10 usec
WPVAL   equ     77/4            ; first cylinder requiring write precomp
HDBASE  equ     80h             ; base of I/O ports for HD controller
ASTCYL  equ     0               ; alternate sector table cylinder adr
ASTHD   equ     2               ; alternate sector table head number
ASTSEC  equ     0               ; alternate sector table starting sector number
ASBASE  equ     ASTSEC+2        ; start of alternate sector pool
MAXAST  equ     MAXSEC-ASBASE+1 ; size of alternate sector pool


;       WD1000 hard disk controller extended port definitions:


HDXCSR  equ     HDBASE+9        ; external control/status port (in/out)




        list    off
*include stddefs.z80            ; library definition files
*include wd1000.z80             ; WD1000 definitions
*maclib  stdmacs.z80            ; library macro routines
        list    on




;########################################################;
;#           USER DEFINABLE PARAMETER AREA              #;
;########################################################;


drive:  defb    0               ; current drive no (initially A)
scyl:   defb    0               ; starting cylinder number
ecyl:   defb    MAXCYL          ; ending cylinder number
mxhead: defb    7               ; maximum head number (initially 7)
ilfact: defb    8               ; inter-leave factor (init = 8)




;########################################################;
;#                   MAIN PROGRAM                       #;
;########################################################;


start:  tstz80                  ; CPU must be Z-80
        ld      sp,stktop
        print   'ZOBEX Hard Disk Format Utility V1.01  (Created 27-Sep-81)'
        call    init
more:   ld      sp,stktop       ; reset stack
        call    menu            ; print menu
        call    getcmd          ; get cmd from user
        call    (hl)            ; process cmd
        br      more            ; do this again




init:   ; Perform initialization for disk format program
        ;
        ld      hl,(boot+1)
        ld      (wsadr),hl      ; save warm boot adr at wsadr
        ld      hl,more
        ld      (boot+1),hl     ; and modify vector to xfr to "more"
        ret




menu:   ; Print menu for disk formatting program
        ;
        print   CR,LF,LF,'Options:'
        print   CR,LF,'  D: Select DISK to format'
        print   CR,LF,'  I: Set Disk INTERLEAVE Factor'
        print   CR,LF,'  F: Format disk to 128 bytes/sector'
        print   CR,LF,'  R: Build bad block REPLACEMENT table'
        print   CR,LF,'  V: Verify disk'
        print   CR,LF,'  E: EXIT to CP/M (Insert system disk first)'
        print   CR,LF,'Drive is '
        ld      a,(drive)
        add     '0'
        chrout
        print   ', interleave factor is '
        ld      hl,(ilfact)
        ld      h,0
        decout
        print   CR,LF,'Selection: '
        ret                     ; that's all




getcmd: ; Input and decode user cmd, return ^ to processing routine in HL
        ;
        call    getcon
        ld      hl,ctblnd       ; HL := ^end of cmd code table
        ld      bc,ctblsz       ; BC := number of table entries
        cpdr                    ; search thru table, bc = 0 if no match
        ld      hl,gotbl        ; HL := ^base of dispatch table
        add     hl,bc
        add     hl,bc           ; HL := ^adr of processing routine
        ld      a,(hl)
        inc     hl
        ld      h,(hl)
        ld      l,a             ; HL := adr of processing routine
        ret                     ; done




gotbl:  ; Dispatch table for cmd processing routines
        ;
        defw    badcmd          ; bad cmd
        defw    seldrv          ; select drive for testing
        defw    ileave          ; set interleave factor
        defw    fmt             ; format 128 bytes/sector disk
        defw    replac          ; build replacement sector table
        defw    verify          ; verify disk
        defw    exit            ; exit to CP/M




ctbl:   ; Command code lookup table
        ;
        defb    -1              ; token illegal character
        defb    'D'             ; select drive for testing
        defb    'I'             ; set interleave factor
        defb    'F'             ; format 128 bytes/sector disk
        defb    'R'             ; build alternate sector table
        defb    'V'             ; verify disk
        defb    'E'             ; exit to CP/M
ctblnd  equ     $-1             ; end of this table
ctblsz  equ     $-ctbl          ; size of this table




;########################################################;
;#              COMMAND PROCESSING ROUTINES             #;
;########################################################;


badcmd: ; Process illegal cmds
        ;
        print   BEL,'?Illegal command',CR,LF
        ret




seldrv: ; Select drive for subsequent formatting
        ;
        print   'Select which drive: '
        call    getcon          ; input drive
        sub     a,'0'           ; convert, qualify drive code
        cp      a,'1'-'0'
        br      gt,baddrv       ; bad drive code
        ld      (drive),a       ; update drive code
        ret
        ;
baddrv: print   BEL,'?Bad drive ID - valid drives are 0 through 1'
        ret




ileave: ; Set sector interleave factor
        ;
        print   'New interleave factor: '
        call    getint
        br      c,badil
        tbr     a,z,badil
        cp      MAXSEC          ; reject the patently absurd cases
        br      gt,badil
        ld      (ilfact),a      ; ok - save it
        ret
        ;
badil:  print   BEL,'?Bad range - must be 1 through '
        decout  MAXSEC
        ret




fmt:    ; Format disk
        ;
        call    recal           ; recalibrate drive
        call    fmtdsk          ; format the disk
        ret                     ; bye




verify: ; Verify disk by reading all sectors
        ;
        print   CR,LF,'?Not implemented'
;       call    chkdsk          ; check the disk
        ret




replac: ; Replace bad sectors.
        ;
        call    recal           ; recalibrate drive
        call    fmtdsk          ; format the disk
        clra
        ld      (astsiz),a      ; clear AST
        fill    ast,ast+[MAXAST*3],0
        print   CR,LF,LF,'Looking for bad sectors - this takes a while'
        print   CR,LF,'Checking pattern # 1'
        ld      hl,8888h
        call    bldast          ; check disk with various patterns
        print   CR,LF,'Checking pattern # 2'
        ld      hl,9249h
        call    bldast
        print   CR,LF,'Checking pattern # 3'
        ld      hl,0e656h
        call    bldast
        print   CR,LF,'Checking pattern # 4'
        ld      hl,0aaaah
        call    bldast
        print   CR,LF,'Checking pattern # 5'
        ld      hl,5555h
        call    bldast
        print   CR,LF,'Checking pattern # 6'
        ld      hl,0f0fh
        call    bldast
        print   CR,LF,'Checking pattern # 7'
        ld      hl,2222h
        call    bldast
        print   CR,LF,'Checking pattern # 8 (this is the last one)'
        ld      hl,0e5e5h
        call    bldast
        print   CR,LF,LF,'Marking sectors to be replaced'
        call    mrkdsk          ; mark bad blocks
        print   CR,LF,'Writing sector replacement table to disk'
        call    putast          ; write AST to disk
        print   CR,LF,LF,'Total of '
        ld      hl,(astsiz)
        ld      h,0
        decout
        print   ' sector(s) replaced'
        ret




exit:   ; Exit to CP/M
        ;
        ld      hl,(wsadr)
        ld      (boot+1),hl     ; restore warm start adr @ boot+1
        rst     0               ; reboot system (hopefully)




;########################################################;
;#                 SUPPORT SUBROUTINES                  #;
;########################################################;


addbb:  ; Add bad block to alternate sector table if not
        ; already present.
        ;
        ld      a,(astsiz)
        ld      b,a             ; B := table size
        ld      hl,ast
abb0:   tbr     b,z,abb4        ; found end of table
        save    hl
        ld      a,(cyl)
        cp      a,(hl)
        jr      ne,abb2         ; cylinders differ
        inc     hl
        ld      a,(head)
        cp      a,(hl)
        jr      ne,abb2         ; heads differ
        inc     hl
        ld      a,(sector)
        cp      a,(hl)
abb2:   restor  hl
        ret     eq              ; already present
        ld      de,3
        add     hl,de           ; move to next entry
        dec     b               ; count down entries
        br      abb0
        ;
abb4:   ld      hl,astsiz
        ld      a,(hl)
        cp      a,MAXAST
        jr      lt,abb6         ; if astsiz > MAXAST then error
        print   CR,LF,BEL,'?Replacement table overflow'
        ret
        ;
abb6:   tbr     (cyl),nz,abb8   ; error if cyl 0, heads 0..2
        ld      a,(head)
        cp      a,2
        br      gt,abb8
        print   BEL,CR,LF,'?Bad sector on system track - cannot proceed'
        jp      more
        ;
abb8:   ld      e,(hl)
        ld      d,0
        inc     (hl)            ; ++astsiz
        ld      hl,ast
        add     hl,de
        add     hl,de
        add     hl,de           ; HL := ast + 3 * (astsiz - 1)
        ld      a,(cyl)         ; store bad block parms in ast
        ld      (hl),a
        inc     hl
        ld      a,(head)
        ld      (hl),a
        inc     hl
        ld      a,(sector)
        ld      (hl),a
        print   CR,LF,'Replacing'
        call    errors
        ret




bldast: ; Build alternate sector table.
        ;
        ; Entry:  HL = pattern to write to disk
        ;
        ex      de,hl
        ld      hl,trkbuf
        ld      bc,[MAXSEC+1]*128 / 2
bast0:  ld      (hl),e          ; fill trkbuf with 16 bit pattern
        inc     hl
        ld      (hl),d
        inc     hl
        dec     bc
        tbr     bc,nz,bast0
        call    putdsk          ; fill disk with pattern
        call    chkdsk          ; read back, add any bad blocks to ast
        ret




bldstt: ; Build sector translation table
        ;
        clra
        ld      (nxtpos),a      ; nxtpos := 0
        ld      (nxtbas),a      ; nxtbas := 0
        ld      (ii),a          ; ii := 0
        ld      hl,ilfact
        ld      a,(hl)          ; A := ilfact
        cp      a,MAXSEC+1
        br      lt,bldst0       ; if ilfact >= MAXSEC+1 then
        ld      a,MAXSEC        ;    ilfact = MAXSEC
bldst0: dec     a
        ld      hl,neltbl
        call    indexa
        ld      a,(hl)
        ld      (nelts),a       ; nelts = maxsec / gcd(maxsec,ilfact-1)
bldst2: ld      a,(nelts)
        ld      (neltst),a
bldst4: ld      hl,stran
        ld      a,(nxtpos)
        save    af
        add     a,a
        call    indexa
        ld      (hl),0
        inc     hl
        ld      a,(ii)
        ld      (hl),a          ; stran[2 * nxtpos] := ii
        restor  af
        ld      hl,ilfact
        add     (hl)
        cp      a,MAXSEC+1
        br      lt,bldst6
        sub     a,MAXSEC+1
bldst6: ld      (nxtpos),a
        ld      hl,ii
        inc     (hl)            ; ii := ii + 1
        ld      a,MAXSEC+1
        cp      (hl)
        ret     le              ; done if MAXSEC+1 <= ii
        ld      hl,neltst
        dec     (hl)
        br      nz,bldst4
        ld      hl,nxtbas
        inc     (hl)
        ld      a,(hl)
        ld      (nxtpos),a
        br      bldst2




chkdsk: ; Check disk for errors
        ;
        ld      a,(scyl)
        ld      (cyl),a         ; cyl := scyl
ckd0:   clra
        ld      (head),a        ; head := 0
ckd2:   call    cchk            ; chk for console break
        call    setsdh          ; select proper head
        call    setcyl          ; set cylinder adr
        call    chktrk          ; check next track
        ld      hl,head
        inc     (hl)            ; head := head + 1
        ld      a,(mxhead)
        cp      a,(hl)
        br      ge,ckd2         ; repeat 'til head > mxhead
        ld      hl,cyl
        inc     (hl)            ; cyl := cyl + 1
        ld      a,(ecyl)
        cp      a,(hl)
        jr      ge,ckd0         ; repeat til cyl > ecyl
        ret




chktrk: ; Check track
        ;
        ; entry parms:
        ;       cyl     = cylinder number
        ;       head    = head number
        ; return parms:
        ;       none
        ;
        clra
        ld      (sector),a      ; sector := 0
        ld      hl,trkbuf
ckt0:   ld      (dmaadr),hl     ; set next dma adr
        ld      hl,sector
        ld      c,(hl)
        save    hl
        call    setsec
        call    rdsec           ; read next sector
        tst     a
        call    nz,addbb        ; add to ast
        restor  hl              ; HL := ^sector
        inc     (hl)            ; sector := sector + 1
        ld      a,MAXSEC
        cp      a,(hl)          ; if sector > MAXSEC then
        ret     lt              ;    exit
        ld      hl,(dmaadr)
        ld      de,128
        add     hl,de           ; dmaadr := dmaadr + 128
        br      ckt0            ; loop 'til all sectors written




errors: ; Print disk address at console.
        ;
        print   ' cylinder '
        ld      hl,(cyl)
        ld      h,0
        decout                  ; print cylinder adr
        print   ', head '
        ld      hl,(head)
        ld      h,0
        decout                  ; print head number
        print   ', sector '
        ld      hl,(sector)
        ld      h,0
        decout                  ; print sector adr
        call    cchk            ; chk for console abort
        ret




fmtdsk: ; Format disk
        ;
        print   LF,'Formatting...',CR,LF
        call    bldstt          ; build sector translation table
        ld      a,(scyl)
        ld      (cyl),a         ; cyl := scyl
fmtd0:  clra
        ld      (head),a        ; head := 0
fmtd2:  call    cchk            ; check for console abort
        call    pwhere          ; print current cylinder, head
        call    setsdh          ; select disk, head
        call    setcyl          ; set cylinder adr
        call    fmttrk          ; format the track
        ld      hl,head
        inc     (hl)            ; head := head + 1
        ld      a,(mxhead)
        cp      a,(hl)
        br      ge,fmtd2        ; repeat 'til head > mxhead
        ld      hl,cyl
        inc     (hl)            ; cyl := cyl + 1
        ld      a,(ecyl)
        cp      a,(hl)          ; if cyl > ecyl then
        ret     lt              ;    exit
        br      fmtd0           ; format another cylinder




gsttp:  ; Get pointer to position in stran for sector
        ;
        ; Entry:  A = sector
        ; Exit:   HL = ^ to first byte of entry in stran
        ;
        ld      hl,stran+1
gsttp0: cp      a,(hl)
        dec     hl              ; HL := ^ first byte
        ret     eq
        inc     hl
        inc     hl              ; HL := ^ next entry
        br      gsttp0




mrkdsk: ; Mark bad blocks on disk.
        ;
        ld      a,(scyl)
        ld      (cyl),a         ; cyl := scyl
mkdk0:  clra
        ld      (head),a        ; head := 0
mkdk2:  call    mrktrk          ; mark next track
        ld      hl,head
        inc     (hl)            ; head := head + 1
        ld      a,(mxhead)
        cp      a,(hl)
        br      ge,mkdk2        ; repeat 'til head > mxhead
        ld      hl,cyl
        inc     (hl)            ; cyl := cyl + 1
        ld      a,(ecyl)
        cp      a,(hl)
        jr      ge,mkdk0        ; repeat til cyl > ecyl
        ret




mrktrk: ; Mark bad blocks on current track
        ;
        call    bldstt          ; build sector translation table
        clra
        ld      (fmtflg),a      ; fmtflg := FALSE
        ld      hl,ast
        ld      a,(astsiz)
        ld      b,a             ; B := table size
mktk0:  tbr     b,z,mktk4       ; found end of table
        save    hl
        ld      a,(cyl)
        cp      a,(hl)
        jr      ne,mktk2        ; cylinders differ
        inc     hl
        ld      a,(head)
        cp      a,(hl)
        jr      ne,mktk2        ; heads differ
        inc     hl
        ld      a,(hl)
        call    gsttp           ; HL := ^ sector in stran
        ld      (hl),080h       ; mark as bad block
        ld      a,TRUE
        ld      (fmtflg),a      ; fmtflg := TRUE
mktk2:  restor  hl
        ld      de,3
        add     hl,de           ; move to next entry
        dec     b               ; count down entries
        br      mktk0
        ;
mktk4:  tret    (fmtflg),z
        call    setsdh          ; select disk, head
        call    setcyl          ; set cylinder adr
        call    fmttrk          ; reformat the track
        ret




putast: ; Put alternate sector table to disk.
        ;
        clra
        ld      (cyl),a         ; cyl := 0
        ld      a,2
        ld      (head),a        ; head := 2
        call    setsdh          ; select disk, head
        call    setcyl          ; set cylinder adr
        clra
        ld      (sector),a      ; sector := 0
        ld      b,2
        ld      hl,astsiz       ; dmaadr := astsiz
past0:  save    bc
        ld      (dmaadr),hl     ; set next dma adr
        ld      bc,(sector)
        call    setsec          ; set sector adr
        call    wrtsec          ; write next sector
        restor  bc
        tbr     a,nz,past2      ; exit if error
        ld      hl,sector
        inc     (hl)            ; sector := sector + 1
        ld      hl,(dmaadr)
        ld      de,128
        add     hl,de           ; dmaadr := dmaadr + 128
        djnz    past0           ; count down sectors
        ret
        ;
past2:  print   BEL,CR,LF,'?Can''t write Sector Replacement Table'
        jp      more




putdsk: ; Fill disk from trkbuf, add any blocks which cannot
        ; be written to ast.
        ;
        ld      a,(scyl)
        ld      (cyl),a         ; cyl := scyl
pdsk0:  clra
        ld      (head),a        ; head := 0
pdsk2:  call    cchk            ; chk for console break
        call    setsdh          ; select proper head
        call    setcyl          ; set cylinder adr
        call    puttrk          ; write next track
        ld      hl,head
        inc     (hl)            ; head := head + 1
        ld      a,(mxhead)
        cp      a,(hl)
        br      ge,pdsk2        ; repeat 'til head > mxhead
        ld      hl,cyl
        inc     (hl)            ; cyl := cyl + 1
        ld      a,(ecyl)
        cp      a,(hl)
        jr      ge,pdsk0        ; repeat til cyl > ecyl
        ret




puttrk: ; Write track
        ;
        ; entry parms:
        ;       cyl     = cylinder number
        ;       head    = head number
        ; return parms:
        ;       none
        ;
        clra
        ld      (sector),a      ; sector := 0
        ld      hl,trkbuf
ptk0:   ld      (dmaadr),hl     ; set next dma adr
        ld      hl,sector
        ld      c,(hl)
        save    hl
        call    setsec
        call    wrtsec          ; read next sector
        tst     a
        call    nz,addbb        ; add to ast
        restor  hl              ; HL := ^sector
        inc     (hl)            ; sector := sector + 1
        ld      a,MAXSEC
        cp      a,(hl)          ; if sector > MAXSEC then
        ret     lt              ;    exit
        ld      hl,(dmaadr)
        ld      de,128
        add     hl,de           ; dmaadr := dmaadr + 128
        br      ptk0            ; loop 'til all sectors written




rderr:  ; Disk hard read error
        ;
        print   BEL,CR,LF,'?Hard read error at'
        call    errors
        print
        ret




pwhere: ; Print cylinder and head numbers at crt
        ;
        print   cr,'Cyl:'       ; print cylinder number
        ld      hl,(cyl)
        ld      h,0
        decout  ,3
        print   ', Head:'       ; print head number
        ld      hl,(head)
        ld      h,0
        decout  ,3
        print   '  '            ; park cursor at end of msg
        ret




getint: ; Input decimal integer from console, convert to binary
        ;
        call    getlin          ; get a line from console
        ret     c               ; null line
        skipbl  ibuf+2          ; scan past leading blanks
        save    de
        alldig                  ; chk if valid number string
        restor  de
        ret     c               ; not valid
        decin                   ; convert to binary
        clrcf
        ret




getcon: ; Input a line from the console and return the first
        ; non-blank character in the line.  This character is
        ; folded to upper case alfa.  Returns NULL if the line
        ; was empty.
        ;
        call    getlin          ; get a line from console
        skipbl  ibuf+2          ; scan past leading blanks
        ld      a,(de)
        call    foldch
        ret




getlin: ; Input a line from the console into ibuf
        ;
        fill    ibuf,ibuf+21    ; clear input buffer to zeroes
        input   ibuf,20         ; input a line
        save    af
        ld      a,LF
        chrout                  ; issue linefeed to console
        restor  af
        ret




cchk:   ; Chk for ^C, abort if found
        ;
        charst                  ; chk if char avail
        tret    a,z             ; none avail
        charin
        cp      a,CTLC
        ret     ne              ; ignore if char <> CTLC
        print   '^C',CR,LF      ; print message, exit to cmd level
        jp      more




foldch: ; Convert character in reg A to upper case
        ;
        cp      a,'a'
        ret     lt
        cp      a,'z'
        ret     gt
        sub     a,'a'-'A'
        ret




indexa: ; Index HL by A
        ;
        add     a,l
        ld      l,a
        ret     nc              ; done if no cy
        inc     h
        ret




;########################################################;
;#                 DISK PRIMITIVES                      #;
;########################################################;


recal:  ; Recalibrate disk drive
        ;
        clra
        ld      (head),a
        call    setsdh          ; select drive, head, sector size
        ld      a,WPVAL
        out     (HDWPC),a       ; init write precomp
        ld      a,HDHOMC | 1111b
        out     (HDCSR),a       ; issue slow recalibrate cmd to get to cyl 0
        call    sekwat          ; wait for seek complete
        ld      a,HDHOMC | RATE
        out     (HDCSR),a       ; do another recalibrate cmd to set proper rate
        call    sekwat          ; wait for seek complete
        ret




fmttrk: ; Format a track
        ;
        call    setsdh          ; select proper head
        ld      a,MAXSEC+1
        out     (HDSECC),a      ; output sector count
        ld      bc,[SECSIZ<<8]|HDDAT ; B := bytes / sector, C := data port adr
        ld      hl,stran
        ld      a,HDFMTC
        out     (HDCSR),a       ; issue format cmd
        call    drqwat          ; wait for DRQ
        otir
        call    bsywat          ; wait for cmd to complete
        in      a,(HDCSR)       ; read HD controller status
        and     a,1<<HERRB|1<<WRTFB     ; mask for errors
        ret     z               ; exit if ok
        print   CR,LF,'?Write track error'
        jp      more            ; back to menu




setsec: ; Set sector number
        ;
        ; entry parms:  C = desired sector number
        ; return parms: none
        ; regs altered: A
        ;
        ld      a,c
        out     (HDSEC),a       ; sector request issued
        ret




setdma: ; Set DMA buffer address
        ;
        ; entry parms:  BC = DMA buffer address
        ; return parms: none
        ;
        ld      (dmaadr),bc     ; save requested DMA buffer adr
        ret




setcyl: ; Set cylinder address
        ;
        ; entry parms:  cyl = desired cylinder address
        ; return parms: none
        ; regs altered: A
        ;
        ld      a,(cyl)
        out     (HDCYLL),a
        clra
        out     (HDCYLH),a
        ret






wrtsec: ; Write disk sector
        ;
        ; entry parms:  none
        ; return parms: A = 0 if no error, 1 if error
        ; regs altered: A, BC, DE, HL
        ;
        call    setsdh          ; select drive, head
        ld      bc,128<<8 | HDDAT
        ld      hl,(dmaadr)
        ld      a,HDWRTC
        out     (HDCSR),a       ; issue write cmd
        call    drqwat          ; wait for DRQ
        otir                    ; fill buffer
        call    bsywat          ; wait for write to complete
        jr      rwxit           ; test for errors, exit




rdsec:  ; Read disk sector
        ;
        ; entry parms:  none
        ; return parms: A = 0 if no error, 1 if error
        ; regs altered: A, BC, DE, HL
        ;
        call    setsdh          ; select drive, head
        ld      a,HDRDC
        out     (HDCSR),a       ; issue read cmd
        call    bsywat          ; wait for read to complete
        ld      bc,128<<8 | HDDAT
        ld      hl,(dmaadr)
        inir                    ; empty buffer
rwxit:  in      a,(HDCSR)
        and     a,1<<HERRB      ; test for errors
        ret




sekwat: ; Wait for seek to complete
        ;
        call    bsywat
sekw0:  in      a,(HDCSR)
        bit     SEKCB,a
        jr      z,sekw0
        ret




setsdh: ; Set sector size, drive and head number
        ;
        ; Entry:   drive = drive #, head = head #
        ; Exit:    nil
        ; Altered:
        ;
        ld      a,(drive)       ; A := drive #
        add     a,a             ; shift drive bits into position
        add     a,a
        add     a,a
        ld      hl,head
        or      a,(hl)          ; or in head select bits
        or      a,SSZ128        ; set sector size code
        out     (HDSDH),a       ; output to controller
        ret




drqwat: ; Wait for DRQ
        ;
        in      a,(HDCSR)
        bit     DRQB,a
        br      z,drqwat
        ret




bsywat: ; Wait for HDC to complete a command.
        ;
        ; Entry parms:  none
        ; Return parms: none
        ; Regs altered: A
        ;
        ex      (sp),hl
        ex      (sp),hl         ; delay for busy to be set
        save    hl,de
        ld      hl,0
        ld      e,6             ; timeout ctr := 60000h
bsyw0:  call    bsycnt          ; update timeout ctr
        br      c,bsyw2         ; time-out error exit
        in      a,(HDCSR)       ; read controller status
        add     a,a             ; CY := bsy bit
        br      c,bsyw0         ; bsy
        restor  de,hl
        ret
        ;
bsyw2:  ; Process WD1000 timeout condition.
        print   BEL,CR,LF,'?Controller timeout error, aborting.'
        jp      more




bsycnt: ; Decrement HDC timeout ctr, return CY set if timeout
        ;
        dec     hl
        tret    hl,nz
        dec     e
        ret     nz
        scf
        ret




;########################################################;
;#                   DEBUG ROUTINES                     #;
;########################################################;


      if DEBUG


dskerr: ; Print error info at console
        ;
        save    hl,de,bc,af     ; save everything in jeopardy
        print   CR,LF,'HDC STATUS - DRV='
        hexout  (drive)
        print   ', HDCSR='
        in      a,(HDCSR)
        hexout                  ; print HDC status register
        print   ', HDERR='
        in      a,(HDERR)
        hexout                  ; print HDC error register
        print   ', CYL='
        in      a,(HDCYLL)
        ld      l,a
        in      a,(HDCYLH)
        ld      h,a
        call    hex16           ; print cylinder
        print   ', HEAD='
        hexout  (head)          ; print desired head
        print   ', HDSEC='
        in      a,(HDSEC)
        hexout                  ; print HDC sector register
        restor  af,bc,de,hl     ; everything restored
        ret




hex16:  ; Print contents of HL in hex at console
        ;
        save    hl
        ld      a,h
        hexout
        restor  hl
        ld      a,l
        hexout
        ret
      endif ; DEBUG




;########################################################;
;#                      TABLES                          #;
;########################################################;


neltbl: ; Table used whilst generating skew table
        ;
        defb     54             ; 1
        defb     27             ; 2
        defb     18             ; 3
        defb     27             ; 4
        defb     54             ; 5
        defb     9              ; 6
        defb     54             ; 7
        defb     27             ; 8
        defb     6              ; 9
        defb     27             ; 10
        defb     54             ; 11
        defb     9              ; 12
        defb     54             ; 13
        defb     27             ; 14
        defb     18             ; 15
        defb     27             ; 16
        defb     54             ; 17
        defb     3              ; 18
        defb     54             ; 19
        defb     27             ; 20
        defb     18             ; 21
        defb     27             ; 22
        defb     54             ; 23
        defb     9              ; 24
        defb     54             ; 25
        defb     27             ; 26
        defb     2              ; 27
        defb     27             ; 28
        defb     54             ; 29
        defb     9              ; 30
        defb     54             ; 31
        defb     27             ; 32
        defb     18             ; 33
        defb     27             ; 34
        defb     54             ; 35
        defb     3              ; 36
        defb     54             ; 37
        defb     27             ; 38
        defb     18             ; 39
        defb     27             ; 40
        defb     54             ; 41
        defb     9              ; 42
        defb     54             ; 43
        defb     27             ; 44
        defb     6              ; 45
        defb     27             ; 46
        defb     54             ; 47
        defb     9              ; 48
        defb     54             ; 49
        defb     27             ; 50
        defb     18             ; 51
        defb     27             ; 52
        defb     54             ; 53






stran:  ; Sector translation table
        ;
        defs    2 * [MAXSEC+1]




;########################################################;
;#                 LOCAL DATA AREA                      #;
;########################################################;


wsadr:  defs    2               ; warm start adr (picked up from boot+1)
lsec:   defs    1               ; current logical sector adr
badsec: defs    1               ; storage for last bad sector
ch:     defs    1               ; storage for chars read from console
ibuf:   defs    22              ; console input buffer


nelts:  defs    1               ; number of stran elements to generate per pass
neltst: defs    1               ; temp version of nelts
nxtpos: defs    1               ; next position in stran array to fill
nxtbas: defs    1               ; next base in stran array
ii:     defs    1               ; index variable
dmaadr: defs    2               ; current DMA adr
cyl:    defs    1               ; current cyl adr
head:   defs    1               ; current head number
sector: defs    1               ; current sector adr
fmtflg: defs    1               ; need to format track if <> 0


astsiz: defs    1               ; current length of AST
ast:    defs    3 * [MAXSEC-ASBASE+1]   ; alternate sector table


        end     start